Встроенный язык и запросы

Язык на русском

Встроенный язык 1С похож на другие языки программирования, только ключевые слова русские. Есть и английские синонимы — If, Then, EndIf, — но в российских компаниях почти везде пишут по-русски.

// Переменные создаются присваиванием
Цена = 1500;
Количество = 3;
Сумма = Цена * Количество;

// Условие
Если Сумма > 10000 Тогда
	Скидка = 5;
ИначеЕсли Сумма > 3000 Тогда
	Скидка = 3;
Иначе
	Скидка = 0;
КонецЕсли;

// Цикл со счётчиком
Для Номер = 1 По 3 Цикл
	Сообщить("Строка " + Номер);
КонецЦикла;

Сообщить("Сумма со скидкой: " + Сумма * (100 - Скидка) / 100);

Каждая команда заканчивается точкой с запятой. Комментарии начинаются с //. Сообщить показывает текст пользователю — удобно для первых опытов.

Код собирают в процедуры и функции. Функция возвращает значение:

Функция СуммаСоСкидкой(Сумма, Скидка)
	Возврат Сумма * (100 - Скидка) / 100;
КонецФункции

Цикл Для Каждого вы уже видели в коде проведения: он перебирает строки табличной части, элементы массива или результат запроса.

Где живёт код

Код в 1С не лежит в отдельных файлах, а привязан к объектам — в модулях:

• модуль объекта — поведение конкретного документа или элемента справочника: проведение, проверки при записи;
• модуль формы — реакция на действия пользователя в окне: нажал кнопку, выбрал товар;
• модуль менеджера — действия с объектами одного вида в целом: например, печать;
• общие модули — процедуры, которые нужны в разных местах конфигурации.

Клиент и сервер

Программа на 1С работает в двух местах: клиент — окна на компьютере пользователя, сервер — где лежат данные. В модуле формы перед процедурой пишут, где она выполняется:

&НаКлиенте
Процедура ПересчитатьСумму(Команда)
	ПересчитатьНаСервере();
КонецПроцедуры

&НаСервере
Процедура ПересчитатьНаСервере()
	// здесь можно читать данные из базы
КонецПроцедуры

Правило: данные из базы читают на сервере, а вызовы с клиента на сервер делают пореже — каждый занимает время. Новичкам это кажется сложным, но привыкают быстро.

Язык запросов

Получать данные из базы удобнее всего запросами. Язык запросов — родственник SQL, только на русском:

Запрос = Новый Запрос;
Запрос.Текст =
	"ВЫБРАТЬ
	|	Остатки.Товар КАК Товар,
	|	Остатки.КоличествоОстаток КАК Остаток
	|ИЗ
	|	РегистрНакопления.ОстаткиТоваров.Остатки(, Склад = &Склад) КАК Остатки
	|УПОРЯДОЧИТЬ ПО
	|	Товар";
Запрос.УстановитьПараметр("Склад", Склад);

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
	Сообщить("" + Выборка.Товар + ": " + Выборка.Остаток);
КонецЦикла;

Что здесь происходит:

• ВЫБРАТЬ … ИЗ … УПОРЯДОЧИТЬ ПО — как SELECT … FROM … ORDER BY в SQL;
• ОстаткиТоваров.Остатки — виртуальная таблица остатков из прошлого урока; в скобках её параметры: дата не указана — значит, текущие остатки, и отбор по складу;
• &Склад — параметр: значение передаётся отдельно методом УстановитьПараметр;
• текст запроса многострочный: каждая новая строка начинается с |;
• Пока Выборка.Следующий() Цикл перебирает строки результата.

Ещё одна особенность — обращение через точку: Остатки.Товар.Артикул достанет артикул товара без явного соединения таблиц. Удобно, но в больших запросах этим не злоупотребляют: каждая точка — скрытое соединение.

Писать запросы вручную с нуля не нужно: в Конфигураторе есть конструктор запроса, где таблицы и поля выбирают мышкой. Но читать и править текст запроса разработчик должен уверенно. Если вы проходили курс «SQL с нуля», половина языка запросов вам уже знакома.

	// записываем движения сейчас, чтобы проверить остатки с их учётом
	Движения.ОстаткиТоваров.Записать();

	Запрос = Новый Запрос;
	Запрос.Текст =
		"ВЫБРАТЬ
		|	Остатки.Товар КАК Товар,
		|	Остатки.КоличествоОстаток КАК Остаток
		|ИЗ
		|	РегистрНакопления.ОстаткиТоваров.Остатки(, Склад = &Склад) КАК Остатки
		|ГДЕ
		|	Остатки.КоличествоОстаток < 0";
	Запрос.УстановитьПараметр("Склад", Склад);

	Выборка = Запрос.Выполнить().Выбрать();
	Пока Выборка.Следующий() Цикл
		Сообщить("Не хватает товара «" + Выборка.Товар + "»: " + (-Выборка.Остаток) + " шт.");
		Отказ = Истина;
	КонецЦикла;